חלק 0: לפני שמתחילים · פרק 3

הכירו את התוכנה

בספר נעבוד עם שלוש תוכנות. אקסל, שנמצא כמעט בכל מחשב ומצוין להכנת נתונים. ושתי תוכנות סטטיסטיות, SPSS ו־JASP, שמריצות בלחיצה את הניתוחים שנלמד. בפרק הזה נכיר את המסך של כל אחת, ונריץ ניתוח ראשון על קובץ המחקר.

שאלת הפתיחה

כמה מרוצים מהחיים 200 התלמידים במחקר, בממוצע?

ביד, זה חיבור של 200 מספרים. בתוכנה, זו שורה אחת. בסוף הפרק תריצו את החישוב בתוכנה שבחרתם, ותדעו לקרוא את התוצאה.

בסוף הפרק תוכלו

לכתוב נוסחה באקסל, לגרור אותה, ולקבע תא בעזרת $.
להשתמש בפונקציות הראשונות: SUM, COUNT, AVERAGE, ROUND ו־SQRT.
לזהות הודעות שגיאה באקסל, ולדעת מה מתקן אותן.
לפתוח את קובץ המחקר ב־SPSS או ב־JASP ולהריץ סטטיסטיקה תיאוריתDescriptive statistics ראשונה.

שלוש תוכנות, תפקיד אחד לכל אחת

אקסל: הכנת נתונים וחישובים פשוטים. SPSS: התוכנה הוותיקה, עם תפריטים ועם סינטקס שאפשר לשכפל. JASP: חינמית, מבוססת על R, ומפיקה טבלאות בסגנון APA. דרך העבודה המומלצת: מכינים באקסל, מנתחים בתוכנה סטטיסטית.

אקסל נמצא כמעט בכל מחשב, והרבה אנשים משתמשים בו בלי לחשוב על סטטיסטיקה בכלל: לתקציב הבית, לרשימת הוצאות, לציונים של כיתה. בשבילנו הוא הכלי הכי טוב להכנת נתונים: להקליד, לתקן, לחבר נתונים ממקורות שונים, ולחשב משתנים חדשים. אפשר לעשות בו גם סטטיסטיקה בסיסית: ממוצעים, מבחני t, מתאםCorrelation, ואפילו ניתוח שונותOne-way ANOVA פשוט. ובפרקים הראשונים של הספר נחשב בו כמעט הכול. אבל אקסל הוא לא תוכנה סטטיסטית. כשהניתוחים נעשים מורכבים, הוא כבר לא מספיק.

SPSS היא התוכנה הסטטיסטית הוותיקה והנפוצה במדעי החברה. אפשר לעבוד בה עם תפריטים, ואפשר לכתוב סינטקס, כלומר פקודות כתובות. כשמריצים את אותו ניתוח על מאה משתנים, סינטקס שמשכפלים ומשנים בו רק את שם המשתנה חוסך המון זמן. וגם בניהול נתונים היא חזקה: לבחור רק חלק מהנבדקים, או לפצל את הניתוח לפי קבוצות, זה כפתור אחד. החיסרון: היא יקרה, ואחרי שמסיימים ללמוד, בדרך כלל כבר אין גישה אליה.

JASP היא תוכנה חינמית, שבנויה על R, השפה שבה עובדים היום חוקרים רבים. אבל ב־R צריך לכתוב קוד, וב־JASP עובדים עם תפריטים. היא נגישה, יפה, והטבלאות שלה יוצאות מוכנות בסגנון APA. החולשה שלה היא הכנת הנתונים: לתקן ולשנות קובץ בתוכה לא נוח. ולכן מכינים את הקובץ באקסל, ופותחים אותו ב־JASP.

הסיפור המלא: ומה עם R ו־jamovi?

כמעט כל מה שיש ב־SPSS קיים היום גם ב־JASP, ויש דברים שקיימים רק בה. למשל ניתוחים בייסיאניים לצד כל מבחן (פרק 40), ומודלים של משוואות מבניות (פרק 39), שב־SPSS דורשים תוכנה נוספת בתשלום, AMOS. תוכנה "תאומה" של JASP היא jamovi, שגם היא חינמית, בנויה על R, ונראית כמעט אותו דבר. היא שימושית במיוחד למודלים לינאריים מעורבים (פרק 36), והמעבר אליה מ־JASP כמעט טריוויאלי. ומי שירצה בהמשך לכתוב קוד, יגיע ל־R עצמה, התוכנה שנחשבת היום ל־state of the art בסטטיסטיקה המחקרית.

ובפועל, רוב החוקרים עובדים עם לפחות שני כלים במקביל, וכל כלי עושה את מה שהוא יודע לעשות הכי טוב. גם אני: בעבודת המחקר שלי אני משתמש לרוב ב־SPSS, אבל לא רק בה. בעבודת תזה, עם שלושה או ארבעה ניתוחים מרכזיים, התפריטים של JASP מספיקים לגמרי. סינטקס משתלם כשמריצים את אותו ניתוח עשרות פעמים. מה שתלמדו בספר יעבור איתכם לכל אחת מהתוכנות: הניתוח זהה, רק המסך שונה.

בדקו את עצמכם3 שאלות

1.בקובץ הנתונים יש שגיאות הקלדה, ואתם צריכים גם לחשב עמודה חדשה של ממוצע. לפי דרך העבודה המומלצת, באיזו תוכנה עושים את זה?

2.חוקרת צריכה להריץ את אותו ניתוח על 60 משתנים שונים. איזו תכונה של SPSS תחסוך לה הכי הרבה זמן?

3.סטודנט מסיים את התואר, ובשנה הבאה ימשיך לנתח נתונים לעבודת התזה שלו מהבית. איזו תוכנה סטטיסטית כדאי לו ללמוד, ולמה?

אקסל: הגיליון ונוסחה ראשונה

כל תא מזוהה בכתובת: עמודה (אות) ושורה (מספר), למשל B4. נוסחה מתחילה תמיד ב־=. התא מציג את התוצאה, ושורת הנוסחאות מציגה את הנוסחה.

גיליון באקסל הוא טבלה ענקית. העמודות מסומנות באותיות, A, B, C, והשורות במספרים, 1, 2, 3. לכל תא יש כתובת: האות של העמודה והמספר של השורה. התא בעמודה B ובשורה 4 הוא B4. טווח של תאים נכתב עם נקודתיים, שפירושן "עד": A2:A6 הם חמשת התאים מ־A2 עד A6.

במסך תראו חמישה דברים חשובים: שורת הנוסחאות מעל הטבלה, תיבת השם משמאלה, שמראה את כתובת התא שנבחר, כותרות העמודות, מספרי השורות, והתא הפעיל, שמסומן במסגרת ירוקה. באקסל בעברית העמודה A עשויה להופיע דווקא מימין. זה לא משנה דבר.

כל נוסחה מתחילה בסימן =. כתבו בתא A1 =3+4*2^2 והקישו Enter. בתא תופיע התוצאה, 19, ובשורת הנוסחאות תראו את הנוסחה. כפל באקסל הוא כוכבית, וחזקה היא ה"כובע", ^.

הפניות לתאים: הקסם של אקסל

במקום מספרים, כותבים בנוסחה כתובות של תאים. אם ב־A2 יש 3 וב־A3 יש 5, הנוסחה =A2+A3 נותנת 8. עכשיו שנו את A2 ל־10, והתוצאה תתעדכן מעצמה ל־15. זה כל הקסם של אקסל: כותבים נוסחה פעם אחת, ומשנים נתונים כמה שרוצים.

הפונקציות הראשונות

הפונקציה	מה היא עושה	על 3, 5, 6, 8, 8 בתאים A2:A6
`=SUM(A2:A6)`	סכום, Σx	30
`=COUNT(A2:A6)`	כמה מספרים יש, n	5
`=AVERAGE(A2:A6)`	ממוצע, M	6
`=SQRT(25)`	שורש	5
`=ROUND(78.3333, 2)`	עיגול לשתי ספרות	78.33

איך כותבים פונקציה בלי לזכור אותה בעל פה? לוחצים על התא, מקלידים = ואת האותיות הראשונות של השם, ואקסל מציע רשימה. בוחרים בדאבל־קליק, מסמנים את הטווח בעכבר, ולוחצים Enter. ואם לא זוכרים אפילו את השם: הכפתור fx שליד שורת הנוסחאות פותח את אשף הפונקציות. בוחרים קטגוריה, למשל Statistical, ובוחרים פונקציה, והאשף שואל על מה לחשב ומסביר כל שדה.

ומה עושים כשלא יודעים איך עושים משהו? מחפשים ברשת. "excel correlation function" מביא את התשובה תוך שנייה, וכך גם "איך ממירים אינצ'ים לסנטימטרים". רוב מי שעובד היטב באקסל לא למד אותו בקורס, אלא כך בדיוק: חיפוש אחד בכל פעם שצריך משהו חדש.

ואם האקסל שלכם בעברית? התפריטים נמצאים באותו מקום כמו באנגלית, רק השמות מתורגמים. בספר אכתוב את שמות התפריטים באנגלית, ולפעמים גם בעברית, למשל View > Freeze Panes (תצוגה > הקפאת חלוניות). כשאין תרגום, חפשו ברשת איך התפריט נקרא בעברית: המיקום זהה, ולפעמים השם משתנה מעט בין גרסאות. ושמות הפונקציות לא מתורגמים בכלל: גם באקסל בעברית כותבים =AVERAGE(A2:A6), ולא "ממוצע".

שימו לב להבדל בין ROUND לבין כפתורי העשרוניות שבסרגל. הכפתורים משנים רק את התצוגה: המספר המלא נשאר בתא, וממשיך להשתתף בחישובים. ROUND משנה את הערך עצמו.

בדקו את עצמכם4 שאלות

1.כתבתם בתא =(2+4)*3^2/6 והקשתם Enter. מה יופיע בתא?

(2 + 4) × 3² / 6

= 6 × 9 / 6

= 54 / 6 = 9

קודם הסוגריים, אחר כך החזקה, ואחר כך כפל וחילוק משמאל לימין. התשובה 8 מתקבלת אם שוכחים את הסוגריים: =2+4*3^2/6.

2.בתאים A2:A7 יש ציוני בוחן: 6, 9, 4, 7, 8, 6. מה יחזירו =SUM(A2:A7), =COUNT(A2:A7) ו־=AVERAGE(A2:A7)? ומה יחזיר =ROUND(6.6667, 2)?

Σx = 6 + 9 + 4 + 7 + 8 + 6 = 40

n = 6

M = 40 / 6 = 6.6667

ROUND(6.6667, 2) = 6.67

הסכום 40, יש 6 מספרים, והממוצע 6.6667, עם עוד הרבה ספרות. ROUND לשתי ספרות נותן 6.67.

3.בתא B1 יש =40/6. לחצתם על כפתור העשרוניות עד שהתא מציג 6.67. עכשיו כותבים בתא B2 =B1*3. מה יופיע ב־B2?

40 / 6 = 6.6666…

6.6666… × 3 = 20

ואילו: 6.67 × 3 = 20.01

הכפתור שינה רק את התצוגה. בתא נשאר 6.6666…, ולכן הכפל נותן 20 בדיוק. התשובה 20.01 הייתה נכונה רק אם היינו מעגלים את הערך עצמו, עם ROUND.

4.כמה תאים יש בטווח B3:B10?

גרירה, והסימן $

נוסחה שגוררים למטה "זזה" יחד איתה: =A2^2 הופכת ל־=A3^2. כדי שתא מסוים לא יזוז, מוסיפים $ לפני האות ולפני המספר: $A$8. קיצור מקלדת: F4.

נניח שאת הערכים 3, 5, 6, 8, 8 הקלדנו בתאים A2 עד A6, ורוצים עמודה של ריבועים. כותבים ב־B2 =A2^2, ואז גוררים את הריבוע הקטן שבפינת התא למטה. אקסל מעתיק את הנוסחה, ובכל שורה היא מתייחסת לתא של השורה שלה: B3 מקבל =A3^2, B4 מקבל =A4^2, וכן הלאה. זו נוסחה דינמית, או בשמה הרשמי, הפניה יחסית. היא תמיד לוקחת "את התא שמשמאלי". טיפ: דאבל־קליק על הריבוע הקטן ממלא את העמודה עד סוף הנתונים, בלי לגרור. הוא ממלא עד השורה האחרונה שיש בה נתונים בעמודה הסמוכה. אם העמודה שלידו ריקה, לא יקרה כלום.

אותו ריבוע קטן, ידית המילוי, יודע גם להמשיך סדרות. מקלידים 1 בתא A2 ו־2 בתא A3, מסמנים את שני התאים, וגוררים למטה: אקסל ממשיך 3, 4, 5. הוא מזהה את הצעד: 2 ו־4 ימשיכו 6, 8, 10, ו־1 ו־1 ימשיכו 1, 1, 1. כך ממלאים עמודת מספרי נבדקים של 200 תלמידים בשנייה. ולמה שני תאים? תא אחד עם מספר, כשגוררים אותו, פשוט מועתק. ומה עם טקסט שמסתיים במספר, כמו a1? גוררים אותו, ומקבלים a2, a3, נוח לשמות של פריטים.

עכשיו רוצים את המרחק של כל ערך מהממוצע. הממוצע נמצא בתא אחד, A8. אם נכתוב ב־C2 =A2-A8 ונגרור, גם A8 יזוז: בשורה הבאה הנוסחה תהיה =A3-A9, ו־A9 ריק. התוצאות יהיו שגויות, ואקסל לא יתריע.

הפתרון: לקבע את התא של הממוצע. כותבים =A2-$A$8. הדולר לפני האות מקבע את העמודה, והדולר לפני המספר מקבע את השורה. כך לנוסחה יש חלק דינמי, A2, שיורד שורה אחרי שורה, וחלק קבוע, הממוצע. במקום להקליד את הדולרים, עומדים על הכתובת בתוך הנוסחה ולוחצים F4 (במחשבים ניידים לפעמים Fn+F4, וב־Mac גם Cmd+T).

להעביר או להעתיק?

יש הבדל חשוב בין העתקה להעברה. כשמעתיקים נוסחה (Ctrl+C ו־Ctrl+V, או גרירה של ידית המילוי), ההפניות היחסיות זזות יחד איתה, בדיוק כמו שראינו. כשמעבירים תאים, גוזרים (Ctrl+X) ומדביקים, או גוררים את התא בגבול שלו, שום דבר לא זז: הנוסחה שומרת על ההפניות שלה. ויותר מזה: כל נוסחה אחרת שהסתכלה על התאים שהועברו, מתעדכנת לכתובת החדשה. הנוסחאות חכמות. לכן אפשר לסדר מחדש את הגיליון בלי לפחד, כל עוד מעבירים ולא מעתיקים.

הסיפור המלא: דולר אחד בלבד

אפשר לקבע רק חלק מהכתובת. $A2 מקבע את העמודה, והשורה זזה. A$2 מקבע את השורה, והעמודה זזה. זו הפניה מעורבת, והיא שימושית כשגוררים נוסחה גם למטה וגם הצידה. הדוגמה הקלאסית היא לוח הכפל: בתאים A2 עד A6 המספרים 1 עד 5, ובתאים B1 עד F1 שוב 1 עד 5. בתא B2 כותבים =$A2*B$1, גוררים ימינה עד F, ואז למטה עד שורה 6. כל תא מכפיל את המספר שבעמודה A, בשורה שלו, במספר שבשורה 1, בעמודה שלו. בתא D4, למשל, הנוסחה היא =$A4*D$1, והתוצאה 3 · 3 = 9.

ומה עושה F4? כל לחיצה מחליפה צורה, במעגל: A2, $A$2, A$2, $A2, וחוזר חלילה. בספר נשתמש כמעט רק בשתי הראשונות. אבל טוב לדעת שהאפשרות קיימת, ואם תרצו אתגר, חפשו ברשת עוד דוגמאות.

דוגמה פתורה: טבלת הסכומים מהפרק הקודם, באקסל

	A	B	C	D
1	שעות	ריבוע	מרחק מהממוצע	ריבוע המרחק
2	3	=A2^2 → 9	=A2-$A$8 → −3	=C2^2 → 9
3–6	5, 6, 8, 8	25, 36, 64, 64	−1, 0, 2, 2	1, 0, 4, 4
7	=SUM(A2:A6) → 30	198	0	18
8	=AVERAGE(A2:A6) → 6

את שורה 7 כותבים פעם אחת בעמודה A וגוררים ימינה. אותם מספרים בדיוק כמו בטבלה של פרק 2, אבל כאן אקסל חישב הכול.

הסיפור המלא: ציון תקן, על הדרך

אותו רעיון של חלק דינמי וחלק קבוע ישמש אותנו בהרבה נוסחאות. למשל ציון תקןz-score: המרחק של כל ערך מהממוצע, ביחידות של סטיית תקן. אם הממוצע ב־A8 וסטיית התקן ב־A9, הנוסחה היא =(A2-$A$8)/$A$9. ציון תקן שלילי אומר "מתחת לממוצע", וחיובי "מעליו". נלמד אותו לעומק בפרק 13. כאן הוא רק דוגמה לנוסחה עם שני תאים מקובעים.

וטיפ: דאבל־קליק על תא עם נוסחה צובע את התאים שהנוסחה משתמשת בהם. ככה רואים מיד אם הדולר במקום.

תורכם

12 תלמידים דיווחו על שעות לימוד בשבוע: 4, 6, 2, 8, 5, 7, 3, 9, 6, 5, 10, 7. הקלידו אותם בתאים B2 עד B13. חשבו את הסכום, את מספר התלמידים ואת הממוצע (בתא B15). אחר כך, בעמודה E, את המרחק של כל תלמיד מהממוצע, ובעמודה F את ריבוע המרחק. מה סכום עמודה E? ומה סכום עמודה F?

בדיקת התשובה

=SUM(B2:B13): 72
=COUNT(B2:B13): 12
=AVERAGE(B2:B13): 6, בתא B15
E2: =B2-$B$15: ‎−2‎, וגוררים עד E13
F2: =E2^2: 4, וגוררים עד F13
=SUM(E2:E13): 0, כמו תמיד
=SUM(F2:F13): 62

קיבלתם מספרים ענקיים בעמודה E? כנראה שכחתם את הדולר. קיבלתם הודעת שגיאה? אולי שורת הכותרת נכנסה לטווח.

בדקו את עצמכם5 שאלות

1.בתא A7 כתובה הנוסחה =SUM(A2:A6). גוררים אותה ימינה, לתא B7. מה תהיה הנוסחה ב־B7?

2.בתאים A2 עד A6 יש 2, 4, 4, 5, 10, וב־A8 הממוצע. בעמודה C חישבתם =A2-$A$8 וגררתם, ובעמודה D את ריבוע המרחק. מה סכום עמודה D?

3.בתאים A2 עד A6 שוב 2, 4, 4, 5, 10, והממוצע 5 ב־A8. הפעם כתבתם ב־C2 =A2-A8 בלי דולר, וגררתם. התא A9 ריק. איזה מספר יופיע ב־C3?

A3 − A9 = 4 − 0 = 4

ועם הדולר: A3 − $A$8 = 4 − 5 = −1

ב־C3 הנוסחה הפכה ל־=A3-A9. תא ריק נחשב 0, ולכן מתקבל 4, הערך עצמו. זה מספר שנראה סביר לגמרי, ואקסל לא מתריע. התשובה הנכונה, −1, הייתה מתקבלת רק עם $A$8.

4.בעמודה A יש את הציונים של התלמידים במבחן, ובתא E1 הציון המקסימלי, 40. כתבו נוסחה לתא B2 שמחשבת את הציון של התלמיד באחוזים, ושאפשר לגרור למטה.

30 / 40 × 100 = 75

=A2/$E$1*100. A2 צריך לזוז שורה אחרי שורה, ולכן בלי דולר. E1 צריך להישאר במקום, ולכן מקבעים אותו. תלמיד עם 30 יקבל 75.

5.בתא B2 כתבתם =$A2*B$1, גררתם ימינה עד עמודה E, ואז למטה עד שורה 5. מה הנוסחה בתא E5?

=$A5*E$1 הדולר לפני A מקבע את העמודה, אבל השורה זזה: מ־2 ל־5. הדולר לפני 1 מקבע את השורה, אבל העמודה זזה: מ־B ל־E. כך כל תא מכפיל את הערך שבעמודה A, בשורה שלו, בערך שבשורה 1, בעמודה שלו. התשובה =A5*E1 נותנת אותה תוצאה בתא הזה, אבל היא לא מה שאקסל כותב: הדולרים נשארים בנוסחה.

הודעות שגיאה, והשגיאה שאין לה הודעה

ההודעה	מה קרה	מה עושים
`#DIV/0!`	חילוק באפס	בודקים את המכנה. אולי הוא תא ריק
`#NAME?`	שם פונקציה שגוי, למשל AVRAGE	מתקנים את האיות
`#VALUE!`	טקסט במקום שצריך מספר	בודקים שבטווח יש רק מספרים
`#####`	העמודה צרה מדי	מרחיבים אותה. דאבל־קליק על הגבול בין העמודות מתאים את הרוחב

הודעות שגיאה הן בעצם חדשות טובות: אקסל אומר לכם שמשהו לא בסדר. השגיאה המסוכנת באמת היא זו שאין עליה הודעה בכלל: סוגריים חסרים, או דולר חסר. אקסל יחשב, ותקבלו תוצאה שגויה שנראית בדיוק כמו תוצאה נכונה. לכן, אחרי כל נוסחה, בדקו שורה אחת ביד.

ועוד עצה לתחילת הדרך: אל תכתבו נוסחה אחת ארוכה שעושה הכול. כתבו כמה נוסחאות קצרות, כל אחת בעמודה משלה, ורק בסוף נוסחה שמחברת ביניהן. נוסחה ארוכה נראית אלגנטית, אבל כשמשהו בה נשבר, קשה לדעת איפה. ועמודות נוספות לא עולות כלום: הגיליון כמעט אינסופי.

מה שרואים אינו תמיד מה שיש בתא

באקסל, התא מציג משהו, ומאחוריו יכול לעמוד ערך אחר. שלוש דוגמאות שכדאי להכיר:

עשרוניות: כפתורי העשרוניות משנים רק את התצוגה, כמו שראינו. ROUND משנה את הערך.
כתיב מדעי: -1.94E-16 הוא בעצם אפס (פרק 2).
תאריכים: תאריך באקסל הוא מספר: כמה ימים עברו מ־1 בינואר 1900. אם מחברים תאריך לטקסט, למשל ="מפגש "&A2, מופיע פתאום מספר כמו 44133. הפונקציות DAY, MONTH ו־YEAR מחלצות ממנו את היום, את החודש ואת השנה.

הסיפור המלא: עברית באקסל, ופונקציות של טקסט

אקסל מציג עברית מימין לשמאל, אבל שומר כל טקסט משמאל לימין. לכן כשמפרקים שם מלא לשם פרטי ולשם משפחה, "שמאל" בפונקציה הוא בעצם תחילת המילה, גם בעברית. הנה איך מפרקים את "ריקרדו טרש" שבתא A2:

=FIND(" ",A2): איפה נמצא הרווח? כאן, במקום ה־7. רווח, כמו כל טקסט בנוסחה, נכתב בתוך גרשיים.
=LEFT(A2,FIND(" ",A2)-1): כל מה שלפני הרווח: ריקרדו.
=LEN(A2): אורך הטקסט כולו: 10 תווים, כולל הרווח.
=RIGHT(A2,LEN(A2)-FIND(" ",A2)): מה שנשאר אחרי הרווח: טרש.
=B2&" "&C2: הכיוון ההפוך: מחברים שם פרטי, רווח ושם משפחה. הסימן & (Shift+7) מחליף את הפונקציה הישנה CONCATENATE.

את כל אלה לא צריך לזכור. מספיק לדעת שזה אפשרי, ולחפש כשצריך.

בדקו את עצמכם4 שאלות

1.רציתם את הממוצע של 6, 9, 12 שבתאים A2, A3, A4, וכתבתם =A2+A3+A4/3. מה יופיע בתא?

6 + 9 + 12 / 3 = 6 + 9 + 4 = 19

(6 + 9 + 12) / 3 = 27 / 3 = 9

חילוק קודם לחיבור, ולכן רק A4 חולק ב־3. זו בדיוק השגיאה שאין לה הודעה: 19 נראה כמו מספר רגיל. הנוסחה הנכונה היא =(A2+A3+A4)/3, או =AVERAGE(A2:A4), שנותנות 9.

2.כתבתם =B2/C2, ובתא C2 עוד לא הקלדתם דבר. איזו הודעה תופיע?

#DIV/0! תא ריק במכנה הוא חילוק באפס. #VALUE! מופיע כשיש טקסט במקום מספר, ופה התא ריק, לא טקסט.

3.מה עדיף: נוסחה אחת ארוכה שעושה הכול, או כמה נוסחאות קצרות בעמודות נפרדות? ולמה?

4.בתא A2 כתוב "מיכל לוי". מה יחזיר =FIND(" ",A2)?

מ־י־כ־ל = 4 תווים

הרווח: 4 + 1 = 5

"מיכל" הוא 4 תווים, והרווח הוא התו החמישי. 4 הוא האורך של השם הפרטי, ולכן LEFT לוקח FIND פחות 1. 8 הוא האורך של כל הטקסט, LEN.

ניתוח ראשון על קובץ המחקר

עכשיו לשאלת הפתיחה: שביעות הרצון מהחיים, לפני התוכנית. בחרו את התוכנה שלכם. בקובץ 200 תלמידים, ושביעות הרצון לפני התוכנית נמצאת בעמודה sat_pre: ממוצע של חמש שאלות, בסולם מ־1 עד 7.

הקובץ, care_school.csv, נמצא גם בתיקיית data בחבילת הספר. בפרק 8 נלמד איך הוא בנוי, משתנה אחר משתנה.

פותחים את הקובץ באקסל. כל שורה היא תלמיד, וכל עמודה משתנה. sat_pre היא עמודה AG.
הקפאת שורת הכותרות, כדי שלא תיעלם כשגוללים: View > Freeze Panes > Freeze Top Row.
בתא ריק: =AVERAGE(AG2:AG201) נותן 5.06. =COUNT(AG2:AG201) נותן 200.
אפשר גם בכלי מוכן: Data > Data Analysis > Descriptive Statistics, Input Range: AG1:AG201, מסמנים Labels in first row ו־Summary statistics. בפעם הראשונה צריך להפעיל את התוסף Analysis ToolPak: File > Options > Add-ins.

sat_pre

Mean	5.06
Standard Error	0.07
Median	5
Mode	4.4
Standard Deviation	1.00
Sample Variance	1.01
Kurtosis	-0.49
Skewness	0.05
Range	4.6
Minimum	2.4
Maximum	7
Sum	1012.8
Count	200

הרבה מספרים. כרגע מספיקים שלושה: Count, כמה תלמידים; Mean, הממוצע; ו־Standard Deviation, סטיית התקן, שנלמד בפרק 11. את השאר נכיר בפרקים 10 עד 12.

ב־SPSS יש שלושה חלונות. Data Editor מציג את הנתונים, ויש לו שתי לשוניות: Data View, הטבלה עצמה, ו־Variable View, ההגדרות של המשתנים. Output Viewer מציג את התוצאות. ו־Syntax Editor מציג פקודות כתובות.

ייבוא: File > Import Data > CSV Data (או Excel), ומסמנים שהשורה הראשונה היא שמות המשתנים. בודקים שיש 200 שורות.
Analyze > Descriptive Statistics > Descriptives. מעבירים את sat_pre לחלון Variable(s), ולוחצים OK.

Descriptive Statistics

	N	Minimum	Maximum	Mean	Std. Deviation
sat_pre	200	2.40	7.00	5.06	1.00
Valid N (listwise)	200

בכל פלט, לפני שמסתכלים על ממוצעים, מסתכלים על N: האם כל התלמידים נכנסו לחישוב?

טיפ: Paste במקום OK. בכל חלון ניתוח יש גם כפתור Paste. הוא לא מריץ, אלא כותב את הפקודה בחלון הסינטקס: DESCRIPTIVES VARIABLES=sat_pre. מריצים אותה בחץ הירוק. כך נשאר תיעוד של כל מה שהרצתם, ואפשר להריץ שוב בלחיצה.

שמירה: File > Save As, בפורמט ‎.sav‎. קובץ sav שומר את הנתונים וגם את כל ההגדרות של המשתנים, שנלמד בפרק 8. קובץ אקסל שומר רק מספרים.

התקנה: באתר jasp-stats.org בוחרים Download, ואת הגרסה של מערכת ההפעלה שלכם: Windows, Mac או Linux. מורידים, מריצים את קובץ ההתקנה, ומופיע הסמל של JASP. התוכנה חינמית. הגרסאות העדכניות מיועדות למחשבים של 64 ביט, וזה המצב כמעט בכל מחשב היום.

פותחים את הקובץ: בתפריט ☰ (שלושת הקווים), Open > Computer > Browse. JASP קורא רק את הגיליון הראשון בקובץ אקסל, ולכן עדיף CSV.
ליד שם כל משתנה יש סמל: סרגל למשתנה כמותי (Scale), עמודות לסדר (Ordinal), ושלושה עיגולים לשמי (Nominal). לחיצה על הסמל משנה אותו. על כך בפרקים 6 ו־8.
Descriptives > Descriptive Statistics, וגוררים את sat_pre לחלון Variables. התוצאה מופיעה מיד, בלי ללחוץ על כלום.

Descriptive Statistics

	sat_pre
Valid	200
Missing	0
Mean	5.06
Std. Deviation	1.00
Minimum	2.40
Maximum	7.00

חלון התוצאות. כל ניתוח שמריצים נוסף כבלוקBlock חדש בחלון התוצאות, מתחת לקודמים, וכל מה שהרצתם קודם נשאר למעלה. לחיצה על כותרת של ניתוח פותחת שוב את ההגדרות שלו: משנים משהו, והתוצאה מתעדכנת במקום. ליד הכותרת יש תפריט קטן, שבו אפשר לשנות לניתוח שם, לשכפל אותו או למחוק אותו. כדאי לתת שמות: אחרי עשרה ניתוחים, "Descriptive Statistics" שמופיע עשר פעמים לא עוזר לאף אחד.

מהפלט אל העבודה. הטבלאות של JASP כבר בנויות בסגנון APA. כדי להעביר טבלה לעבודה: מעמידים את העכבר על כותרת הטבלה, פותחים את התפריט הקטן שמופיע לידה, ובוחרים Copy. מדביקים ב־Word, והטבלה מגיעה מעוצבת, מוכנה לעבודה סמינריונית או לתזה. ב־Word בעברית בדקו שסדר העמודות לא התהפך מימין לשמאל.

JASP ואקסל עובדים יחד. דאבל־קליק על תא בחלון הנתונים פותח את הקובץ באקסל. מוסיפים שם עמודה או מתקנים טעות, שומרים וסוגרים, ו־JASP מתעדכן לבד, כולל כל הניתוחים שכבר הרצתם. זו דרך העבודה שתלווה אותנו: מכינים באקסל, מנתחים ב־JASP.

עוד שלושה כלים: פיצול לפי קבוצות: גוררים משתנה, למשל group, לחלון Split. סינון: לוחצים על כותרת עמודה בחלון הנתונים ומבטלים ערכים. ומודולים נוספים: כפתור ה־+ בפינת סרגל הניתוחים.

התשובה לשאלת הפתיחה: שביעות הרצון הממוצעת היא 5.06, בסולם מ־1 עד 7, מתוך 200 תלמידים. אותו מספר בכל שלוש התוכנות. ובפרק 21 נשאל אם התוכניות שינו אותה.

בדקו את עצמכם4 שאלות

1.בפלט של ניתוח תיאורי כתוב: Valid 196, Missing 4. מה זה אומר?

2.בפלט תיאורי של העמודה anx_pre מופיעים Sum = 447.125 ו־N = 200. מה הממוצע, בעיגול לשתי ספרות?

3.העמודה vol_pre היא 0 או 1: האם התלמיד התנדב לעזור בתחילת השנה. הממוצע שלה הוא 0.38. מה המשמעות?

4.הרצתם סטטיסטיקה תיאורית על siblings, מספר האחים. התקבל N = 200, M = 4.75, Minimum 0, Maximum 99. מה מחשיד בפלט, ומה כדאי לבדוק?

טעויות נפוצות

שוכחים לקבע. גם למרצים זה קורה: כותבים נוסחה עם הממוצע, גוררים, ושוכחים שהממוצע צריך להישאר במקום. התוצאות נראות סבירות, ושגויות. דאבל־קליק על התא מראה מיד לאן הנוסחה "מסתכלת".
שורת הכותרת בתוך הטווח. =AVERAGE(B1:B13) כשב־B1 יש טקסט. רוב הפונקציות מתעלמות מטקסט, אבל בחישובים אחרים תקבלו #VALUE!.
עיגול בתצוגה ובערך. כפתורי העשרוניות לא משנים את הערך. לחישוב מעוגל משתמשים ב־ROUND.
לא בודקים את N. בכל תוכנה, הדבר הראשון שבודקים בפלט הוא כמה נבדקים נכנסו לחישוב.

בדקו את עצמכם

סיכום

מכינים באקסל, מנתחים בתוכנה סטטיסטית. SPSS ותיקה ובתשלום, עם סינטקס. JASP חינמית, עם טבלאות APA.
נוסחה מתחילה ב־=, ומשתמשת בכתובות של תאים, כדי שתתעדכן כשהנתונים משתנים.
גרירה מזיזה את הכתובות. $ (או F4) מקבע תא. העברה של תאים, לעומת זאת, לא מזיזה אף הפניה.
ידית המילוי מעתיקה נוסחאות וממשיכה סדרות: 1, 2 נגררים ל־3, 4, 5.
בפלט, קודם N. אחר כך הממוצע.

מונחים חדשים

תא וכתובתטווחנוסחהפונקציההפניה יחסיתהפניה מוחלטת ($)ידית מילויData View, Variable Viewסינטקס

בפרק הבא מתחילים את חלק א: מחקר ונתונים. איך הופכים שאלה מעניינת על בית ספר לשאלת מחקרResearch question, ולהשערה שאפשר לבדוק.